script_enemy_main{


//Argument 0 = Left, 1 = Right

	#include_function".\..\function\glo_enemydrop.txt";




	let ne_image = GetCurrentScriptDirectory~"..\img\enemy\ghostmale.png";









	let enemyframe1 = 1;

	let e_frametime = 0;
	let e_vanishframe = 235;

//-------------------------------------------------------------------------------------------------
// Any Task







//--------------------------------------------------------------------------------------------------------------

    @Initialize
	{
	SetLife(75);
	SetDamageRate(0,0);
	SetInvincibility(20);
	LoadGraphic(ne_image);

	SetMovePosition02(GetX, GetY, 0);
	}

//--------------------------------------------------------------------------------------------------------------

    @MainLoop
	{
	SetDamageRate(70+(6*GetCommonDataDefault("CD_PowerUse",0)),35+(3*GetCommonDataDefault("CD_PowerUse",0)));

	SetCollisionA(GetX, GetY, 32);
	if ((GetPlayerType == REIMU_A) || (GetPlayerType == REIMU_B))
	{	SetCollisionB(GetX, GetY, 0);	}	else
	{	SetCollisionB(GetX, GetY, 16);	}

	SetShotDirectionType(ABSOLUTE);

//----------------------
// Attack script below
//----------------------

	if (e_frametime == 1)
	{
	if (GetArgument == 0)	{	SetMovePositionHermite(GetX+100, GetY+100, 100, 0, 100, 90, 90);	}
	else	{	SetMovePositionHermite(GetX-100, GetY+100, 100, 180, 100, 90, 90);	}
	}

	if (e_frametime == 90)
	{
	SetMovePosition02(GetX, GetY+100, 120);
	}

	if (e_frametime == 210)
	{
	if (GetArgument == 0)	{	SetMovePosition02(GetClipMinX-60, GetY+50, 30);	}
	else	{	SetMovePosition02(GetClipMaxX+60, GetY+50, 30);	}
	}

	if (enemyframe1%60 == 0)
	{
	PlaySE(GetCurrentScriptDirectory~"..\sfx\Shot1.wav");
	if (GetCommonData("CD_gamemode") == 2)
		{
		ascent (i in 0..10)
			{
			ascent (j in 0..5)
				{
				CreateShot02(GetX, GetY, 0, GetAngleToPlayer+(i*36), 0.2, 5, RED11, 5+(j*5));
				}
			}
		}
	else
		{
		ascent (i in 0..5)
			{
			ascent (j in 0..5)
				{
				CreateShot02(GetX, GetY, 0, GetAngleToPlayer+(i*72), 0.2, 5, RED11, 5+(j*5));
				}
			}
		}
	enemyframe1 = 0;
	}




	enemyframe1++;


//----------------------
// Attack script above
//----------------------

	if ((e_frametime >= e_vanishframe) || (GetX < GetClipMinX-50) || (GetX > GetClipMaxX+50)
	 || (GetY < GetClipMinY-50) || (GetY > GetClipMaxY+50))
		{
		VanishEnemy;
		}

	e_frametime++;
	}




//--------------------------------------------------------------------------------------------------------------

    @Finalize
	{
	if ((BeVanished == false) && (OnBomb == false))
		{
		EnemyDropItem(1, 3);
		EnemyDropItem(3, 2);
		SetCommonData("CD_Feverscore", GetCommonDataDefault("CD_Feverscore",0) + 1000);
		}
	AddScore(5000 * GetCommonDataDefault("CD_FeverMultiplyUse",1) * GetCommonDataDefault("CD_gamemode",1));
	}

//--------------------------------------------------------------------------------------------------------------

    @DrawLoop
	{
	SetTexture(ne_image);
	SetGraphicRect(0, 0, 30, 30);
	SetColor(255, 255, 255);
	SetRenderState(ALPHA);
	SetGraphicAngle(0, 0, 0);
	DrawGraphic(GetX, GetY);
	}
}